SQLite

Artifact d27b76db9639f17c24dcd24e803c9e5e8f9eac23:

• File tool/mksqlite3h.tcl — part of check-in [7f4810747b] at 2009-08-11 05:50:37 on branch trunk — Instead of adding SQLITE_API macros sqlite3.h while creating sqlite3.c, add them as part of generating the sqlite3.h target, while copying from sqlite.h.in to sqlite3.h. This fixes a build problem that was causing multiple SQLITE_API macros to be added to a single line of sqlite3.h, and the problem cited by #4016. (CVS 6971) (user: danielk1977 size: 1439)

#!/usr/bin/tclsh
#
# This script performs processing on src/sqlite.h.in. It:
#
#   1) Adds SQLITE_EXTERN in front of the declaration of global variables,
#   2) Adds SQLITE_API in front of the declaration of API functions,
#   3) Replaces the string --VERS-- with the current library version, 
#      formatted as a string (e.g. "3.6.17"), and
#   4) Replaces the string --VERSION-NUMBER-- with current library version,
#      formatted as an integer (e.g. "3006017").
#
# This script reads from stdin, and outputs to stdout. The current library
# version number should be passed as the only argument. Example invocation:
#
#   cat sqlite.h.in | mksqlite3h.tcl 3.6.17 > sqlite3.h
#

set zVersion [lindex $argv 0]
set nVersion [eval format "%d%03d%03d" [split $zVersion .]]

while {![eof stdin]} {
  set varpattern {^[a-zA-Z][a-zA-Z_0-9 *]+sqlite3_[_a-zA-Z0-9]+(\[|;| =)}
  set declpattern {^ *[a-zA-Z][a-zA-Z_0-9 ]+ \**sqlite3_[_a-zA-Z0-9]+\(}

  set line [gets stdin]

  regsub -- --VERS--           $line $zVersion line
  regsub -- --VERSION-NUMBER-- $line $nVersion line

  if {[regexp {define SQLITE_EXTERN extern} $line]} {
    puts $line
    puts [gets stdin]
    puts ""
    puts "#ifndef SQLITE_API"
    puts "# define SQLITE_API"
    puts "#endif"
    set line ""
  }

  if {([regexp $varpattern $line] && ![regexp {^ *typedef} $line])
   || ([regexp $declpattern $line])
  } {
    set line "SQLITE_API $line"
  }
  puts $line
}